MSWLogo tạo hình chuyển động

Mswlogo làm hình động.

Để tạo hiệu ứng chuyển động trong Mswlogo thì cách đơn giản nhất là bắt chước như làm phim hoạt hình, vẽ liên tục các ảnh khác nhau rồi cho nó chiếu – hiển thị – từng hình một:Ví dụ

Repeat 360 [Repeat 4 [Fd 100 Rt 90] Rt 1 Clean]

Trong ví dụ trên hình vuông sẽ được vẽ sau đó rùa xoay phải 1 độ và lệnh Clean sẽ xóa màn hình nhưng không thay đổi vị trí và góc rùa, lặp lại quá trình vẽ, xoay, xóa liên tục ta được hiệu ứng chuyển động xoay tròn của hình vuông

Cũng ví dụ trên sử dụng lệnh PE để xóa nét vẽ rồi vẽ lại ở vị trí khác. Trong ví dụ này ta phải thêm lệnh wait vào, nếu không máy sẽ chạy rất nhanh và bạn không thể thấy được chuyển động. Lệnh PENNORMAL sẽ thiết lập rùa về trạng thái ban đầu, nếu bạn sử dụng màu sắc cho nét vẽ thì dùng lệnh PENPAINT viết tắt PPT để thiết lập lại rùa thoát khỏi chế độ xóa.

Repeat 360 [Repeat 4 [Fd 100 Rt 90] Wait 10 PE Repeat 4 [Fd 100 Rt 90] PENNORMAL Rt 1 Clean]

Bài tập: Dùng Mswlogo mô phỏng chuyển động của hình lục giác sau :

Sau đây là gợi ý cách giải của thầy Nguyễn Lộc

TO A

CS SETPC [0 255 0]
REPEAT 6[REPEAT 3[FD 100 RT 360/3] RT 360/6]

END

TO B

LT 360/6 FD 100 RT 360/6
SETPC [255 0 0]
FD 100 RT 360/3 FD 100
PU FD 100 LT 360/3 PD
FD 100 LT 360/3 FD 100 RT 360/6
REPEAT 3[FD 100 RT 360/3]
RT 360/6
REPEAT 3[FD 100 RT 360/3]
PU RT 360/6 BK 100 LT 360/6 PD

END

TO C

PE FD 100 RT 360/3 FD 100
PU FD 100 LT 360/3 PD
FD 100 LT 360/3 FD 100 RT 360/6
REPEAT 3[FD 100 RT 360/3]
RT 360/6
REPEAT 3[FD 100 RT 360/3]
PPT
SETPC [255 0 0]
RT 360/6
FD 100 RT 360/3 FD 100
PU FD 100 LT 360/3 PD
FD 100 LT 360/3 FD 100 RT 360/6
REPEAT 3[FD 100 RT 360/3]
RT 360/6
REPEAT 3[FD 100 RT 360/3]
PU RT 360/6 BK 100 LT 360/6 PD

END

TO LucGiacXoay

A B C
REPEAT 600[C WAIT 10]

END

Cách giải của emyeutinhoc.com

Cách giải khác, cách này sử dụng biến mảng lưu giữ lại tọa độ 6 đỉnh của lục giác ứng với mỗi đỉnh thì rùa phải xoay một góc tương ứng để vẽ ra lục giác màu đỏ. Việc này được thực hiện bởi chương trình Kt biến của nó chính là vị trí đỉnh của lục giác.

To Kt :k

PU    Home
If :k=1 [ SetPos :A1 RT 30]
If :k=2 [ SetPos :A2 RT 90]
If :k=3 [ SetPos :A3 RT 150]
If :k=4 [ SetPos :A4 LT 150]
If :k=5 [ SetPos :A5 LT 90]
If :k=6 [ SetPos :A6 LT 30]

END

To LucGiac ;Vẽ và lấy tọa độ 6 đỉnh lục giác xanh

FD 100 RT 360/6 Make “A1 Pos
FD 100 RT 360/6 Make “A2 Pos
FD 100 RT 360/6 Make “A3 Pos
FD 100 RT 360/6 Make “A4 Pos
FD 100 RT 360/6 Make “A5 Pos
FD 100 RT 360/6 Make “A6 Pos
SetPos :A6    SetPos :A3    SetPos :A4 ;Nối các đường chéo
SetPos :A1    SetPos :A2    SetPos :A5

End

To LucGiacDo ; Vẽ lục giác màu đỏ

SETPENCOLOR [255 0 0]
Repeat 4 [fd 100 rt 360/6]
LT 60    BK 100    RT 60
TamGiac
RT 60    FD 100    LT 120
TamGiac

End

To TamGiac

Repeat 3 [Fd 100 Rt 360/3]

End

To LucGiacXoay

Ht    Cs    PPT
SETPENSIZE [2 2]
SETPENCOLOR [0 0 255]
Rt 30    LucGiac
Repeat 100 [
For [i 1 6 1] [

KT :i
PD    PPT    Lucgiacdo
Wait 5    KT :i    PE
Lucgiacdo

    ] ;FOR
] ;Repeat

End